C =============================================================================

C DETERMINATION OF LOCAL DENSITIES & TEMPERATURES USING "FINE-GRID"
C THERMOSPHERE LOOK-UP TABLE AND ANALYTIC EXOSPHERE MODEL.
C [29Jan02 JBishop]
C
C although solar angle XL is included in call statement, this
C version is for spherically symmetric atmosphere models

      SUBROUTINE DLOCAL(ITHERM,THERMO,RL,XL,HLOC,O2LOC,TLOC)

      IMPLICIT REAL*8 (A-H,O-Z)

      DIMENSION THERMO(5,ITHERM+1)

      COMMON /EXOS/  GM,CONL,PLANETR,RBASE,RC,RUPR,RP,TEXO,DEXO,VELT,
     &               RADPF,CENTER,ABSCSX,FTSAT,FDSAT,IGEO
      COMMON /NMBR/  PI,RTPI,PID2,OFFSET

C -----------------------------------------------------------------------------
C  EXOSPHERE SEGMENT
C -----------------------------------------------------------------------------

      IF (RL.GT.(RC*(1.0D0 + OFFSET))) THEN

        CALL CORONA(RL,HLOC,TLOC)
        O2LOC = 0.0D0

C -----------------------------------------------------------------------------
C  WANDERED BELOW DESIGNATED PERMITTED REGION (roundoff errors)
C -----------------------------------------------------------------------------

      ELSE IF (RL.LE.THERMO(2,1)) THEN

        HLOC  = EXP( THERMO(4,1) )
        O2LOC = EXP( THERMO(5,1) )
        TLOC  = THERMO(3,1)

C -----------------------------------------------------------------------------
C  THERMOSPHERE
C -----------------------------------------------------------------------------

      ELSE

C FIND CURRENT RADIAL BIN

        IHI = ITHERM + 1
        ILO = 1

 101    IF ((IHI-ILO).GT.1) THEN
          II = (IHI + ILO) / 2
          IF (THERMO(2,II).GT.RL) THEN 
            IHI = II
          ELSE
            ILO = II
          END IF
          GO TO 101
        END IF

C SIMPLE INTERPOLATIONS

        RATIO = (RL-THERMO(2,ILO)) / (THERMO(2,IHI)-THERMO(2,ILO))
        XPNT  = THERMO(4,ILO) + RATIO * (THERMO(4,IHI)-THERMO(4,ILO))
        HLOC  = EXP( XPNT )
        XPNT  = THERMO(5,ILO) + RATIO * (THERMO(5,IHI)-THERMO(5,ILO))
        O2LOC = EXP( XPNT )
        TLOC  = THERMO(3,ILO) + RATIO * (THERMO(3,IHI)-THERMO(3,ILO))

      END IF

C -----------------------------------------------------------------------------

      RETURN
      END

C =============================================================================