C =============================================================================

C ROUTINE TO EVALUATE INCREMENTS TO LINE-OF-SIGHT OPTICAL DEPTHS
C OVER ZONES AND DARK SEGMENTS.

C -----------------------------------------------------------------------------
C   TO2LOC . . . LOCAL INCREMENT TO O2 PHOTOABSORPTION OPTICAL DEPTH
C   TLPLOC . . . LOCAL INCREMENT TO H  SCATTERING OPTICAL DEPTH
C                TLPLOC(LP = 0): LINE CENTER TAU INCREMENT AT TEXO
C                TLPLOC(LP > 0): TAU INCREMENT AT DISPLACEMENT SPDPT(LP)
C                                AT LOCAL TEMPERATURE
C -----------------------------------------------------------------------------

      SUBROUTINE STEP_TAU(ITHERM, THERMO, R1, X1, PARAM_IN,
     &                    DL_B, DL_A, LPROF, SPDPT, TO2LOC, TLPLOC)

      IMPLICIT REAL*8 (A-H,O-Z)

      DIMENSION THERMO(5,ITHERM+1)
      DIMENSION SPDPT(LPROF),TLPLOC(0 : 16)

      DIMENSION PARAM_IN(13)

      COMMON /EXOS/  GM,CONL,PLANETR,RBASE,RC,RUPR,RP,TEXO,DEXO,VELT,
     &               RADPF,CENTER,ABSCSX,FTSAT,FDSAT,IGEO
      COMMON /NMBR/  PI,RTPI,PID2,OFFSET
      COMMON /GAUS08/WW08(08),XX08(08)

C -----------------------------------------------------------------------------
C LOS PARAMETERS FROM PARAM_IN
C -----------------------------------------------------------------------------

      THETA = PARAM_IN( 1)
      CX1   = PARAM_IN( 2)
      SX1   = PARAM_IN( 3)
      CU1   = PARAM_IN( 4)
      SU1   = PARAM_IN( 5)
      CP1   = PARAM_IN( 6)
      SP1   = PARAM_IN( 7)
      RSMU  = PARAM_IN( 8)
      DSMU  = PARAM_IN( 9)
      XSKIM = PARAM_IN(10)
      XTOT  = PARAM_IN(11)
      OSKIM = PARAM_IN(12)
      OTOT  = PARAM_IN(13)

C -----------------------------------------------------------------------------
C INITIALIZE OPTICAL DEPTH INCREMENTS
C -----------------------------------------------------------------------------

      TO2LOC = 0.0D0

      DO LP = 0,LPROF
        TLPLOC(LP) = 0.0D0
      END DO

C -----------------------------------------------------------------------------
C DO IT
C -----------------------------------------------------------------------------

      DO ITAU = 1,8

        DL    = ( (DL_B - DL_A) * XX08(ITAU) + (DL_B + DL_A) ) / 2.0D0
        WDL   =   (DL_B - DL_A) * WW08(ITAU) / 2.0D0
        RL    = SQRT(R1**2 + DL**2 - 2.0D0*R1*DL*COS(PI-THETA))
        OMEGL = THETA - ASIN(RSMU/RL)
        XL    = ACOS( CX1*COS(OMEGL) + SX1*SIN(OMEGL)*CP1 )

        CALL DLOCAL(ITHERM,THERMO,RL,XL,HLOC,O2LOC,TLOC)

        TO2LOC    = TO2LOC    + WDL * ABSCSX * O2LOC
        TLPLOC(0) = TLPLOC(0) + WDL * CENTER * HLOC

        FCTR = SQRT(TEXO/TLOC)
        DO LP = 1,LPROF
          XPNT = (SPDPT(LP)*FCTR)**2
          TLPLOC(LP) = TLPLOC(LP) + WDL*CENTER*HLOC*FCTR * EXP(-XPNT)
        END DO

      END DO

C -----------------------------------------------------------------------------

      RETURN
      END

C =============================================================================