;
pro conimage_event, ev
@pltdat.h
widget_control,ev.id,get_uvalue=uval
case uval of
  "DONE": begin
    widget_control,/destroy,ev.top
    for i=0,2 do widget_control,wb_types(i),set_button=0
    return
  end
  "LOG10": begin
    if conimage.log10 le 0 then begin
      conimage.log10 = 1
      print,'Will plot log10 of field'
    endif else begin
      conimage.log10 = 0
      print,'Will NOT plot log10 of field'
    endelse
    return
  end
  "TXT_TOPLAB": begin
    widget_control,ev.id,get_value=value
    frame.toplab = value(0)
    print,'Will use top label: ',frame.toplab
  end
  "TXT_XLAB": begin
    widget_control,ev.id,get_value=value
    frame.xlab = value(0)
    print,'Will use x-axis label: ',frame.xlab
  end
  "TXT_YLAB": begin
    widget_control,ev.id,get_value=value
    frame.ylab = value(0)
    print,'Will use y-axis label: ',frame.ylab
  end
  "TXT_BOTLAB": begin
    widget_control,ev.id,get_value=value
    frame.botlab = value(0)
    print,'Will use bottom label: ',frame.botlab
  end
  "MAKEFRAME": begin
    widget_control,/hourglass
    erase
    pltconimage
    if writecgm then wrcgm,'conimage'
    if psdev.writeps then wrps,'conimage'
    return
  end
  else: print,'conimage: unknown user value=',uval
endcase
return
end
;
;------------------------------------------------------------------
;
pro popup_conimage
@pltdat.h
;
conimagebase = widget_base(title='2-D CONTOUR and/or IMAGE',/column)
;
base = widget_base(conimagebase,/nonexclusive,/frame,row=1)
wlog10 = widget_button(base,value='PLOT LOG10',uvalue='LOG10')
;
; Change xlab,ylab,toplab,botlab
xsiz = 50
base = widget_base(conimagebase,/column,/frame)
wlab_toplab = widget_label(base,value='Top Label')
wtxt_toplab = widget_text(base,/editable,value=frame.toplab,$
  uvalue='TXT_TOPLAB',xsize=xsiz)
wlab_xlab = widget_label(base,value='X-axis Label')
wtxt_xlab = widget_text(base,/editable,value=frame.xlab,uvalue='TXT_XLAB',$
  xsize=xsiz)
wlab_ylab = widget_label(base,value='Y-axis Label')
wtxt_ylab = widget_text(base,/editable,value=frame.ylab,uvalue='TXT_YLAB',$
  xsize=xsiz)
wlab_botlab = widget_label(base,value='Bottom Label')
wtxt_botlab = widget_text(base,/editable,value=frame.botlab,$
  uvalue='TXT_BOTLAB',xsize=xsiz)
;
base = widget_base(conimagebase,/frame,row=1)
quit = widget_button(base,value="DONE",uvalue="DONE")
mkframe = widget_button(base,value="MAKE FRAME",uvalue="MAKEFRAME")
;
widget_control,conimagebase,/realize
offxy = offset(appbase,conimagebase)
widget_control,conimagebase,tlb_set_xoffset=offxy(0),tlb_set_yoffset=offxy(1)
xmanager,'conimage',conimagebase
return
end