pro wrps,type,surf=srf
@pltdat.h
;
; Remake a frame to postscript device 
; (device file has been opened in ps_event)
;
print,' '
widget_control,/hourglass
print,format="('Writing postscript frame ',i3,' to file ',a,' ...')",$
  psdev.ifrps,psdev.psname
if n_elements(srf) le 0 then srf = 0
save_dev = !d.name
set_plot,'ps'
loadct,idlct,file=!clrtabfile
fixclrtab
if cont.conclr eq white then cont.conclr=!d.table_size-1
if map.continents eq white then map.continents=!d.table_size-1
if map.grid eq white then map.grid=!d.table_size-1
white = !d.table_size-1
erase
widget_control,/hourglass
if imcon eq 1 or vec.ivec eq 1 then begin
  conclr_save = cont.conclr
  cont.conclr = black
  vecclr_save = vec.vclr
  vec.vclr = black 
  if map.continents gt -1 then begin
    continents_save = map.continents
    map.continents = black
  endif
  if map.grid gt -1 then begin
    grid_save = map.grid
    map.grid = black
  endif
  print,'  Note: setting color black for postscript...'
endif    
case type of
  "map": begin
    case map.proj of
      "GLOBAL CYLINDRICAL EQUIDISTANT": begin
        if vec.ivec ne 1 then pltce,/ps $
        else begin
          xll = .15 & yll = .48
          xur = .95 & yur = yll+.5*(xur-xll)
          pltce_vec,[xll,yll,xur,yur],/ps,/backgnd
        endelse
      end
      "POLAR STEREOGRAPHIC": begin
        if vec.ivec ne 1 then pltst,/ps $
        else begin
          xur = .87 & yur = .89
          xll = .13 & yll = .15
          pltst_vec,[xll,yll,xur,yur],/ps,/backgnd
        endelse
      end
      "SATELLITE VIEW": pltsv,/ps
      "MOLLWEIDE": pltmw,/ps
      else: begin
        print,'wrps: unknown map projection: ',map.proj
        return
      end
    endcase
  end
  "conimage": begin
    pltconimage,/ps
  end
  else: begin
    print,'>>> wrps: unknown type=',type
    return
  end
endcase
if imcon eq 1 or vec.ivec eq 1 then begin
  cont.conclr = conclr_save
  vec.vclr = vecclr_save 
  if map.continents gt -1 then map.continents = continents_save
  if map.grid gt -1 then map.grid = grid_save
endif    
set_plot,save_dev
print,format="('Completed writing ps frame ',i3,' to file ',a)",$
  psdev.ifrps,psdev.psname
psdev.ifrps = psdev.ifrps+1
return
end