c
c------------------------------------------------------------------
c Begin file /home/sting/foster/timesdif/pltlat.f
c------------------------------------------------------------------
c
      subroutine pltlat(utc,fld,ihtsc)
c
c Contour latitude slices (lon on x-axis, zp on y-axis)
c
      include 'gettime.h'
      include 'timesdif.h'
      character*56 toplab,lab
      dimension plt(imx,kmx),viewport(4),yaxht(kmx),
     +  fld(imx,kmx,jmx,nplfld)
      data viewport /.15,.89,.26,.91/
c
      if (nlat.le.0) then
        write(6,"('pltlat: no selected latitudes -- returning')")
        return
      endif
      xmid = 0.5*(viewport(1)+viewport(2))
      call cpseti('SET',0)
      call cpseti('MAP',0)
      call cpsetr('XC1',gcmlon(1))
      call cpsetr('XCM',gcmlon(imx))
      call cpsetr('YC1',zprange(1))
      call cpsetr('YCN',zprange(2))
      call cpsetr('ILX',xmid)
      call cpsetr('ILY',-.20)
      call cpseti('ILP',0)
      call set(viewport(1),viewport(2),viewport(3),viewport(4),
     +         gcmlon(1),gcmlon(imx),gcmzp(izprange(1)),
     +         gcmzp(izprange(2)),1)
c
c Field loop: 
      nzp = izprange(2)-izprange(1)+1
      ixp = 0
      do 200 ip=1,ntimefld
        if (ipltime(ip).le.0) goto 200
        ixp = ixp+1
c
c Selected latitude loop:
c
        do 100 j=1,nlat
          ixlat = ixfind(gcmlat,jmx,slat(j),dlon)
          if (ixlat.le.0) then
            write(6,"('>>> pltlatzp: bad latitude=',f10.3,' j=',i3,
     +        ' skipping this lat')") slat(j),j
            goto 100
          endif
          rlat = gcmlat(ixlat)
c
          do k=izprange(1),izprange(2)
            do i=1,imx
               plt(i,k-izprange(1)+1) = fld(i,k,ixlat,ixp)
            enddo
          enddo
          if (icolor.le.0) then
            call contour(plt,imx,imx,nzp,cint(ip),cmin(ip),cmax(ip))
          else
            call conclr(plt,imx,imx,nzp,cint(ip),cmin(ip),cmax(ip))
          endif
          call labrect(gcmlon,imx,gcmzp(izprange(1)),nzp,
     +      'LONGITUDE','ZP',0.)
c
c Top label:
          if (wtime(ip).gt.0.) then
            write(toplab,"(a8,' (% DIFFERENCE)  LAT=',f8.2,' UT=',
     +        f6.2,9x)") timelab_short(ip),rlat,utc
          else
            write(toplab,"(a8,' (RAW DIFFERENCE)  LAT=',f8.2,' UT=',
     +        f6.2,7x)") timelab_short(ip),rlat,utc
          endif
          call wrlab(toplab(1:lenstr(toplab)),xmid,viewport(4)+0.05,0.)
c
c History vols label:
          write(lab,"(2x,'Difference of TIGCM histories ',a8,
     +      ' minus ',a8,1x)") cpertvol,ccntrvol
          call wrlab(lab(1:lenstr(lab)),xmid,viewport(3)-.09,.012)
          call frame
          iframe = iframe+1
          write(6,"('pltlat: frame ',i4,' field ',a8,' lat=',f8.2,
     +      ' zprange=',2f8.2)") iframe,timelab_short(ip),rlat,zprange
c
c End selected latitude loop
 100    continue
c
c End field loop: ip=1,ntimefld
 200  continue
c
      return
      end