c
      subroutine pltdop(fdop,ixl,emislab)
      include 'timesloc.h'
c
c Make line plots of doppler fields with ut on x-axis, fields on y-axis 
c The four doppler fields are tn,un,vn, and brightness (rayleighs)
c   (brightness is vertical integration of vol emission rate)
c
      dimension fdop(ntms,nloc,4)
      dimension vp(4),plt(ntms)
      character*(*) emislab
      character*56 toplab,ylab,rangelab
      character*32 dopname(4)
      data vp /0.14,0.95,0.25,0.90/
      data dopname
     + /'DOPPLER TN (DEG K)              ',
     +  'DOPPLER UN (M/S)                ',
     +  'DOPPLER VN (M/S)                ',
     +  'DOPPLER BRIGHTNESS (RAYLEIGHS)  '/
c
c Set up AG:
c
      call agsetf('DASH/PATTERNS/1.',65535.)
      call agsetc ('LABEL/NAME.','T')
      call agsetr("AXIS/TOP/CONTROL.",-1.)
      call agseti ('LINE/NUMBER.', 100)
      call agsetf ('LINE/CHARACTER.', .025)
      call agsetc("LABEL/NAME.","B")
      call agsetr("LABEL/DEF/SUPPRESSION.",1.)
      call agsetr("AXIS/BOT/CONTROL.",-1.)
      call set(vp(1),vp(2),vp(3),vp(4),0.,1.,0.,1.,1)
c
c lset=2 -> AG will use only fractional from set call
      lset = 2 
c
      call clearstr(toplab)
      if (gloc(1,ixl).eq.gmflag.and.gloc(2,ixl).eq.gmflag) then
        write(toplab,"('GLOBAL MEANS')") 
      elseif (gloc(1,ixl).ne.gmflag.and.gloc(2,ixl).eq.gmflag) then
        write(toplab,"('LAT= ',f6.2,' LON=ZONAL MEANS')")
     +    gloc(1,ixl)
      else
        if (locslt.le.0) then ! at lat,lon
          if (locname(1).ne.'xxxxxxxxxxxxxxxx') then
            write(toplab,"('LAT, LON = ',f6.2,', ',f7.2,' (',a,')')")
     +        gloc(1,ixl),gloc(2,ixl),
     +        locname(ixl)(1:lenstr(locname(ixl)))
          else
            write(toplab,"('LAT, LON = ',f6.2,', ',f7.2)")
     +        gloc(1,ixl),gloc(2,ixl)
          endif
        else ! at lat and fixed local time
          write(toplab,"('LAT, SLT = ',f6.2,', ',f7.2)")
     +      gloc(1,ixl),gloc(2,ixl)
        endif
      endif
      lentop = lenstr(toplab)
c
c Field loop (doptn,un,vn,ray):
      do ip=1,4
        plt(:) = fdop(:,ixl,ip)
        call fminmax(plt,ntms,rmin,rmax,cpspval)
        call clearstr(rangelab)
        write(rangelab,"('MIN, MAX=',e12.4,', ',e12.4)")
     +    rmin,rmax
        lenr = lenstr(rangelab)
        call clearstr(ylab)
        write(ylab,"(a,' (from ',a,')')") 
     +    dopname(ip)(1:lenstr(dopname(ip))),emislab
        leny = lenstr(ylab)
        call displa(2,1,1)
        call anotat('UT (HRS)',ylab(1:leny),0,lset,-1,l)
        call ezxy(utinc,plt,ntms,toplab(1:lentop))
        call fminmax(fdop(1,ixl,ip),ntms,rmin,rmax,cpspval)
        if (rmin.lt.0..and.rmax.gt.0.) 
     +    call line(utinc(1),0.,utinc(ntms),0.)
        isltax = 0
        if (gloc(2,ixl).ge.-180..and.gloc(2,ixl).le.180.) isltax = 1
        if (locslt.gt.0) isltax = 0
        call labutxy(mtimes,ntms,0.,0,' ',0.,isltax,gloc(2,ixl))
        call wrlab(ylab(1:leny),0.5*(vp(1)+vp(2)),vp(4)+.07,0.)
        xoff = .23
        if (isltax.le.0) xoff = .13
        call wrlab(rangelab(1:lenr),0.5*(vp(1)+vp(2)),vp(3)-xoff,0.)
        call frame
        iframe = iframe+1
        write(6,"('pltdop frame ',i4,' field ',a,' ',a)") iframe,
     +    ylab(1:leny),toplab(1:lentop)
        if (iwrascii.gt.0) then
          call wrascii(iwrascii,luascii,plt,ntms,1,utinc,dum,
     +      'UT (HRS)',' ',histvol(ivol),ylab(1:leny),
     +      iframe,toplab(1:lentop),'timesloc',dirascii)
        endif
c
c End field loop:
      enddo
      return
      end