c
c------------------------------------------------------------------
c
      subroutine putlatlt(utf,l)
c
c Contour ut on x-axis, lat on y-axis at selected zp or ht and fixed 
c local times (analogous to pltutlat at selected longitudes):
c
      include 'timesloc.h'
      character*80 rec80,toplab,fieldlab
      dimension viewport(4),yaxht(kmx),rimx(imx),plt(ntms,jmx),
     +  utf(ntms,jmx,nfplt,nzphtslt)
      data viewport /.15,.89,.26,.91/
      data ncalls/0/
      save ncalls
c
      ncalls = ncalls+1
      xmid = 0.5*(viewport(1)+viewport(2))
      rily = -.17
      call cpseti('SET',0)
      call cpseti('MAP',0)
      call cpsetr('XC1',utinc(1))
      call cpsetr('XCM',utinc(ntms))
      call cpsetr('ILX',xmid)
      call cpsetr('ILY',rily)
      call cpseti('ILP',0)
      call cpsetr('ILS',.016)
      if (labels.le.1) call cpsetr('ILS',.018)
      call cpsetr('YC1',gcmlat(1))
      call cpsetr('YCN',gcmlat(jmx))
      call set(viewport(1),viewport(2),viewport(3),viewport(4),
     +         utinc(1),utinc(ntms),-90.,90.,1)
c
c Field loop: 
c
      do 200 ip=1,nftot
        if (ifplt(ip).le.0) goto 200
        plt(:,:) = utf(:,:,ifplt(ip),l)
        if (logutlat.gt.0.and.logterp(ip).gt.0) 
     +    call log10f(plt,ntms*jmx,1.e-20,cpspval)
c
c Contour:
c
        if (labels.gt.1) then
          if (icolor.le.0) then
            call contour(plt,ntms,ntms,jmx,cint(ip),cmin(ip),cmax(ip))
          else
            call conclr(plt,ntms,ntms,jmx,cint(ip),cmin(ip),cmax(ip))
          endif
        else
          call cpcnrc(plt,ntms,ntms,jmx,0.,0.,finc,1,-1,-1634B)
        endif
c
c Add axes labels:
c
        call labutxy(mtimes,ntms,gcmlat,jmx,'LATITUDE (DEG)',0.,0,0.)
c
c Field label at top:
c
        call clearstr(toplab)
        if (logutlat.gt.0.and.logterp(ip).gt.0) then
          write(toplab,"('LOG10 ',a)") flab(ip)
        else
          write(toplab,"(a)") flab(ip)
        endif
        if (ip.eq.ixui.or.ip.eq.ixvi.or.ip.eq.ixwi) then
          len = lenstr(toplab)
          if (ionvel.eq.1) then
            write(toplab(len+1:len+11),"('(no efield)')") 
          elseif (ionvel.eq.2) then
            write(toplab(len+1:len+13),"('(with efield)')") 
          elseif (ionvel.eq.3) then
            write(toplab(len+1:len+13),"('(from epoten)')") 
          endif 
        endif
        call wrlab(toplab(1:lenstr(toplab)),xmid,viewport(4)+0.07,0.)
        fieldlab = toplab
c
c "location" lab:
c
        call clearstr(toplab)
        xoff = .15
c
c At selected zp and slt:
        if (izphtslt(1,l).gt.0) then
          write(toplab,"('ZP=',f5.1,' SLT=',f6.2)") 
     +      (zphtslt(i,l),i=1,2)
c
c At selected height and slt:
        else
          write(toplab,"('HT=',f6.2,' SLT=',f7.2)") 
     +      (zphtslt(i,l),i=1,2)
        endif
        call wrlab(toplab(1:lenstr(toplab)),xmid,viewport(4)+0.03,0.)
        call clearstr(rec80)
        write(rec80,"(a)") toplab(1:lenstr(toplab))
c
c History volume label at bottom:
c
        if (labels.gt.1) then
          call clearstr(toplab)
          if (nhvols.eq.1) then
            write(toplab,"('HISTORY=',a)") histvol(ivol)
          else
            write(toplab,"('FIRST HISTORY VOL=',a)") histvol(ivol)
          endif
          call wrlab(toplab(1:lenstr(toplab)),xmid,viewport(3)-xoff,
     +      .010)
        endif
c
c Wrap it up:
        call frame
        iframe = iframe+1
        if (iwrascii.gt.0) then
          call wrascii(iwrascii,luascii,plt,ntms,jmx,utinc,gcmlat,
     +      'UT (HRS)','LATITUDE (DEG)',histvol(ivol),fieldlab,
     +      iframe,rec80,'timesloc',dirascii)
        endif
        if (izphtslt(1,l).gt.0) then
          write(6,"('utlat(slt) frame ',i3,' field ',a,' zp=',f5.1,
     +      ' slt=',f8.2)") iframe,labshort(ip),zphtslt(1,l),
     +      zphtslt(2,l)
        else
          write(6,"('utlat(slt) frame ',i3,' field ',a,' ht=',f5.1,
     +      ' slt=',f8.2)") iframe,labshort(ip),zphtslt(1,l),
     +      zphtslt(2,l)
        endif
c
c End field loop
 200  continue
c
      return
      end