Rich:

I have put ascii data of timesgcm NO on anonymous ftp on the
machine hao.hao.ucar.edu in the dir pub/foster. The file is
named timesgcm.no.dat. There is data from two frames, the
first is with ZP on the y-axis (ZP are our pressure coords,
in this case the full vertical range of the model, i.e., -17.
to +5 (its ln(p0/p)). The second frame is for height on the
y-axis from 30 to 150 km, every 2 km (the lower part of the 
model).

There is a 4 line header at the beginning of each frame, followed
by a line giving the number of x values, then several lines giving
the x-values themselves, then a line giving the number of y values, 
followed by several lines of the y-values themselves. This is followed 
immediately by the 2d data, with x varying first. You can see by just 
editing the file. All axes and data are printed with format e13.5
Its crude, but simple.

Note that these are raw numbers, i.e., no log10 was taken. I 
believe that the plots you have received earlier plotted log10.
Contours without log10 are not very interesting.
Also note that 1.E+37 is a special value, probably where there
was no model data at the bottom (e.g., 30 km is missing at some
latitudes). Also, I think there are a few negative values near
the bottom to watch for when you take log10.

--Ben

Here's a small idl procedure that will read the data:


function rdascii,lu,flnm,frame
;
; Read data from ascii file flnm, and return a frame structure in "frame":
;
on_ioerror,bad
hdr = strarr(4)
line = '' & line = string(line,format="(a80)")
nx=1 & ny=1
for i=0,3 do begin
  readf,lu,line
  hdr(i) = strtrim(line,2)
endfor
;
; nx, xx:
;
readf,lu,line
nx = 0 & reads,line,nx,format="(3x,i4)"
xx = fltarr(nx) & readf,lu,xx
;
; ny, yy:
;
readf,lu,line
ny = 0 & reads,line,ny,format="(3x,i4)"
yy = fltarr(ny) & readf,lu,yy
;
; Now the data:
;
zz = fltarr(nx,ny)
readf,lu,zz
;
frame = {		$
  hdr:hdr,		$
  nx:nx,		$
  xx:xx,		$
  xlab:hdr(1),		$
  ny:ny,		$
  yy:yy,		$
  ylab:hdr(2),		$
  zz:zz,		$
  toplab:hdr(0),	$
  botlab:hdr(3)		}

;
return,0
bad:
  print,'>>> rdascii: i/o error reading from file ',flnm,$
    ' -- please try again'
  if nx eq 1 or ny eq 1 then begin
    print,'(Looks like this frame is single dimensioned (nx,ny=',$
      nx,ny,')'
    print,' -- sorry, line plots are not yet available'
  endif
  return,1
end