c
c------------------------------------------------------------------
c Begin file /home/sting/foster/proclib/mkver63.f
c------------------------------------------------------------------
c
      subroutine mkver63(ht,tn,te,xo2,xo,xn2,xo2p,xne,
     +  verout,kmx,isr63,slt,day,f107,f107a,glat,glon)
c
c Find volume emission rate at 6300A
c
c On input:
c   ht,tn,te = tigcm height, neutral temp, and electron temp columns
c   xo2,xo,xn2,xo2p,xne are number densities
c   if isr63 > 0 -> add sr63 from solred module
c   if isr63 > 0, then:
c     slt,day = solar local time, and day of year (e.g., 80)
c     f107,f107a = 10.7 cm flux, and 81-day ave flux
c     glat,glon = geographic lat,lon (deg)
c
c On output:
c   verout = vol emission rate (with sr63 added in if isr63 > 0)
c
c Note: ht,tn,te, all input densities, and verout output are dimensioned kmx
c       (kmx=25, to match kmx parameter statements in solred)
c       (This is checked only if isr63 > 0)
c Note: slt and day may actually not be used by solred, depending on a flag
c
c 2/26/92: copied over from proclib because need to pass kmx to solred
c
      dimension ht(kmx),tn(kmx),te(kmx),xo2(kmx),xo(kmx),xn2(kmx),
     +          xo2p(kmx),xne(kmx),verout(kmx),sr63(kmx)
      data ifrst/0/
      data b1d/1.2/, rk3/8.e-12/, a1d/0.0093/, a6300/0.0071/            
c
      ifrst = ifrst+1
      do 100 k=1,kmx                                                   
        rk1 = 2.e-11 * exp(107.8/tn(k))                                 
        rk2 = 2.9e-11 * exp(67.5/tn(k))                                 
        if (te(k).ge.1200.) rkdr = 1.6e-7 * (te(k)/300.)**(-0.55)       
        if (te(k).lt.1200.) rkdr = 1.95e-7 * (te(k)/300.)**(-0.7)       
c
c Dissociative recombination of o2p:
        verout(k) = (b1d * rkdr * xo2p(k) * xne(k)) /               
     +          (a1d + rk1*xn2(k) + rk2*xo2(k) + rk3*xo(k)) * a6300  
 100  continue                                                          
      if (isr63.gt.0) then
        call solred(ifrst,slt,ht,xo,xo2,xn2,tn,sr63,f107,f107a,
     +    day,glat,glon,kmx)
        verout(:) = verout(:) + sr63(:) 
      endif
      return
      end