To: alkim
Subject: o3


Alkim:

I get a different plot than you do, e.g., look at the
postscript file hao.hao.ucar.edu:/pub/foster/o3.ut13.lat2.5.ps.
This was made from the ut13 data I sent last April. I don't
know why you are getting those weird zig-zags -- better check
your idl procedure, and the numbers I sent against the 
idl plot. Maybe even send me the idl procedure and data if
you can't figure out why we're getting different plots.
Here's my code (I broke out frame 13 from the original
ut13 data file):

--Ben

;
function rdascii,lu,flnm,frame
;
; Read data from ascii file flnm, and return a frame structure:
;
; Four line header, to be used later as follows: 
; line 1: top label
; line 2: x-axis label
; line 3: y-axis label
; line 4: bottom label
;
on_ioerror,bad
hdr = strarr(4)
line = ''
line = string(line,format="(a80)")
nx=1 & ny=1
for i=0,3 do begin
  readf,lu,line
  hdr(i) = strtrim(line,2)
endfor
;
; nx, xx:
;
readf,lu,line
nx = 0
reads,line,nx,format="(3x,i4)"
xx = fltarr(nx)
readf,lu,xx
;
; ny, yy:
;
readf,lu,line
ny = 0
reads,line,ny,format="(3x,i4)"
yy = fltarr(ny)
readf,lu,yy
;
; Now the data:
;
zz = fltarr(nx,ny)
readf,lu,zz
;
frame = {		$
  hdr:hdr,		$
  nx:nx,		$
  xx:xx,		$
  xlab:hdr(1),		$
  ny:ny,		$
  yy:yy,		$
  ylab:hdr(2),		$
  zz:zz,		$
  toplab:hdr(0),	$
  botlab:hdr(3)		}

;
return,0
bad:
print,'>>> rdascii: i/o error reading from file ',flnm,$
  ' -- please try again'
return,1
end
;
;---------------------------------------------------------------------
;
pro xylon,flnm,frame,ps=ps
;
; To confirm Alkim's o3 plots at 2.5 lat, 90km:
;
; Read lat slice frame from ascii file flnm and xy plot with lon on x-axis
; (for lat slice, xx=lon, yy=ht)
;
on_ioerror,bad
openr,lu,flnm,/get_lun
ier = rdascii(lu,flnm,frame)
ht = 90.	; want to make xy plot at 90 km
kk = -1
for k=0,frame.ny-1 do begin
  if frame.yy(k) eq ht then kk = k
endfor
if kk lt 0 then begin
  print,'Cannot find ht ',ht,' in yy=' & print,frame.yy
endif
yy = frame.zz(*,kk)
if keyword_set(ps) then set_plot,'ps'
plot,frame.xx,yy,title=frame.botlab
if keyword_set(ps) then device,/close
return
bad:
print,'>>> I/O error from file ',flnm
return
end