#!/bin/tcsh
#
# Make storm case runs of tiegcm (dec2006, jul2000, nov2003, whi2008)
#
# $home:      Base working directory
# $modelroot: Model root directory (with src, scripts, etc)
# $tgcmrun:   Path to tgcmrun executable (python)
#
 set home      = /glade/p/hao/tgcm/tiegcm2.0/benchmarks
 set modelroot = /glade/p/hao/tgcm/tiegcm2.0/tiegcm2.0
 set tgcmdata  = /glade/p/hao/tgcm/data/tiegcm2.0
 set tgcmdata  = /glade/p/hao/tgcm/data/tiegcm2.0
 set tgcmrun   = $modelroot/tgcmrun/tgcmrun
 set queue     = regular # for LSF jobs
 set submit    = yes     # if yes, execute or submit, as appropriate

 set resolutions = ( \
   '5.0' \
   '2.5' \
 )

 set runs = ( \
   dec2006_heelis_gpi \
   dec2006_weimer_imf \
   jul2000_heelis_gpi \
   jul2000_weimer_imf \
   nov2003_heelis_gpi \
   nov2003_weimer_imf \
   whi2008_heelis_gpi \
   whi2008_weimer_imf \
 )

foreach res ($resolutions)

  set case   = tiegcm_res${res}_storms
  set work   = $home/$case
 
  foreach run ($runs)
    echo "------------------ $run --------------------"
    set stdout  = $work/tiegcm_res${res}_$run/stdout
    set histdir = $work/tiegcm_res${res}_$run/hist
    set execdir = $work/tiegcm_res${res}_$run/exec
   
   $tgcmrun -q $queue -run_name $run -model_name tiegcm -model_res $res \
     -model_root $modelroot -stdout_dir $stdout -execdir $execdir \
     -hist_dir $histdir -submit $submit -tgcmdata $tgcmdata
  end # foreach run

end # foreach res

